home *** CD-ROM | disk | FTP | other *** search
/ Belgian Amiga Club - ADF Collection / BS1 part 05.zip / BS1 part 5 / SASC_6.0_Disk_7.adf / Source_And_Examples / source / cback.a < prev    next >
Encoding:
Text File  |  1992-07-30  |  21.2 KB  |  621 lines
  1. *
  2. * C initial startup procedure under AmigaDOS
  3. * 
  4.  
  5.         INCLUDE "exec/types.i"
  6.         INCLUDE "exec/alerts.i"
  7.         INCLUDE "exec/nodes.i"
  8.         INCLUDE "exec/lists.i"
  9.         INCLUDE "exec/ports.i"
  10.         INCLUDE "exec/libraries.i"
  11.         INCLUDE "exec/tasks.i"
  12.         INCLUDE "exec/memory.i"
  13.         INCLUDE "exec/execbase.i"
  14.         INCLUDE "libraries/dos.i"
  15.         INCLUDE "libraries/dosextens.i"
  16. FUNCDEF         MACRO   * function
  17. _LVO\1          EQU     FUNC_CNT
  18. FUNC_CNT        SET     FUNC_CNT-6
  19.                 ENDM
  20.  
  21. FUNC_CNT        SET     LIB_NONSTD
  22.  
  23.         INCLUDE "exec/exec_lib.i"
  24.         INCLUDE "libraries/dos_lib.i"
  25.         INCLUDE "workbench/startup.i"
  26.  
  27. AbsExecBase EQU 4
  28.  
  29. TINY    EQU     0
  30. callsys macro
  31.         CALLLIB _LVO\1
  32.         endm
  33.         
  34.         xdef        _XCEXIT               ; exit(code) is standard way to leave C.
  35.         xdef         @_XCEXIT
  36.         
  37.         xref        LinkerDB              ; linker defined base value
  38.         xref        _BSSBAS               ; linker defined base of BSS
  39.         xref        _BSSLEN               ; linker defined length of BSS
  40.  
  41.         xref        __main                ; Name of C program to start with.
  42.         xref        __fpinit              * initialize floating point
  43.         xref        __fpterm              * terminate floating point
  44.  
  45. *        library references
  46.  
  47.         csect       _NOMERGE,0,0,0,4
  48.         xref        _MemCleanup
  49.         xref        __savecli
  50.         xref        __freecli
  51.         xref        FindTask
  52.  
  53. start:
  54.         movem.l d1-d6/a0-a6,-(a7)
  55. REGSIZE EQU     (6+7)*4
  56.         lea     REGSIZE(a7),A5         * determine old stack pointer
  57.         move.l  a0,a2                  * save command pointer
  58.         move.l  d0,d2                  * and command length
  59.         lea     LinkerDB,a4            * load base register
  60.  
  61.         move.l  AbsExecBase.W,a6
  62.         move.l  a6,SysBase(A4)
  63.         move.l  a7,_StackPtr(A4)       * Save stack ptr
  64.         clr.l   _WBenchMsg(A4)
  65.  
  66. *------        Clear out our BSS section
  67.         lea     _BSSBAS,a3             * get base of BSS
  68.         moveq   #0,d1
  69.         move.l  #_BSSLEN,d0            * get length of BSS in longwords
  70.         bra.s   clr_lp                 * and clear for length given
  71. clr_bss move.l  d1,(a3)+
  72. clr_lp  dbf     d0,clr_bss
  73.  
  74. *------ get the address of our task
  75.         move.l        ThisTask(a6),A3
  76.  
  77. *-----  clear any pending signals
  78.         moveq        #0,d0
  79.         move.l       #$00003000,d1
  80.         callsys      SetSignal
  81.  
  82. *------ are we running as a son of Workbench?
  83.         move.l       pr_CurrentDir(A3),__curdir(A4)
  84.         tst.l        pr_CLI(A3)
  85.         beq          fromWorkbench
  86.  
  87. *=======================================================================
  88. *====== CLI Startup Code ===============================================
  89. *=======================================================================
  90.  
  91. fromCLI:
  92. *------        attempt to open DOS library:
  93.         bsr.w        openDOS
  94.  
  95. *------ Duplicate the current directory for the called process
  96.         move.l        __curdir(A4),D1
  97.         move.l        DOSBase(A4),A6
  98.         callsys       DupLock
  99.         move.l        D0,__curdir(A4)
  100.  
  101. *------ Save the current CLI info including path for child to use
  102.         pea            cli
  103.         jsr            __savecli(pc)   
  104.         addq.l         #4,a7
  105.  
  106. *------ find command name:
  107.         move.l        pr_CLI(A3),a0
  108.         add.l         a0,a0                        ; bcpl pointer conversion
  109.         add.l         a0,a0
  110.         move.l        cli_CommandName(a0),a1
  111.         add.l         a1,a1                        ; bcpl pointer conversion
  112.         add.l         a1,a1
  113.  
  114. *------        collect parameters:
  115.         move.l        d2,d0                        ; get command line length
  116.         moveq.l       #0,d1
  117.         move.b        (a1)+,d1
  118.         move.l        A1,D4                        ;save our pointer
  119.         move.l        d1,d3
  120.         add.l         d1,d1                        ; double length since we copy it twice
  121.         add.l         d1,d0                        ; add length of command name
  122.         addq.l        #5,d0                        ; allow for space after command        
  123.         addq.l        #4,d0                        ; As well as for the roundup
  124. *                          ; changed from 5 to 9 for quotes
  125. *                                         
  126. *------        We have the length of the command string to be copied.
  127. *------        Allocate space for it.
  128. *------        Round up to the nearest 4 bytes
  129.         lsl.l         #2,d0
  130.         add.l         memsize(A4),d0
  131.         move.l        d0,memsize(A4)
  132.  
  133. ************************************************************************
  134. ************************************************************************
  135. ******** Allocate and copy over the code to do the magic stuff *********
  136. ************************************************************************
  137. ************************************************************************
  138.  
  139.         lea           memlist(A4),A0
  140.         move.l        AbsExecBase.W,a6
  141.         callsys       AllocEntry                ;get a place to put the code
  142. *        btst.l        #31,d0                     ;did we get the memory we asked for?
  143. *        beq           cliexit                    ;no, can't do anything then
  144.         move.l        D0,A1
  145.         move.l        D0,-(A7)                  ;remember the chunk we allocated
  146.  
  147. *------ Now we copy the code over
  148.         movea.l       ML_SIZE+ME_ADDR(A1),A1   ;locate our allocated block
  149.  
  150. *------        Copy over the command line to the allocated area
  151.         lea           commandbuf-copybeg(A1),A3
  152.  
  153. *------        At this point, we have:
  154. *                A0 - Work pointer
  155. *                A1 - Pointer to Allocated memory block
  156. *                A2 - Pointer to program name
  157. *                A3 - Pointer to target buffer
  158. *                A3 - Pointer to our process structure
  159. *                D0 - Work register
  160. *                D1 - Work register
  161. *                D2 - length of command name
  162. *                D3 - length of program name
  163. *                D4 - Pointer to program name
  164.  
  165.         move.l        d2,argslen                 ; save length of args
  166.         move.l        d3,proglen                 ; save length of prog
  167.         
  168.         movea.l       D4,A0                      ; Load program name
  169.         move.l        D3,D0                      ;      and length
  170.         move.b        #'"',(a3)+
  171.         bra.s         cpy1
  172. cpycmd: move.b        (A0)+,(A3)+                ; copy over the command name
  173. cpy1:   dbf           d0,cpycmd
  174.         move.b        #'"',(a3)+
  175.         move.b        #' ',(A3)+                 ; add the space delimiter
  176.  
  177.         move.l        A2,A0                      ; Load command text
  178.         move.l        D2,D0                      ;      and length
  179.         bra.s         cpy2
  180. cpylin: move.b        (A0)+,(A3)+
  181. cpy2:   dbf           d0,cpylin
  182.         clr.b         (A3)+
  183.  
  184. *------        Now copy over the program name
  185.         move.l        A3,_ProgramName(A4)
  186.         move.l        D4,A0
  187.         move.l        D3,D0
  188.         bra.s         cpy3
  189. cpypgm: move.b        (A0)+,(A3)+
  190. cpy3:   dbf           D0,cpypgm
  191.         clr.b         (A3)                        ;don't forget trailing null on name
  192.  
  193. *------ First we want to put it into our seglist
  194.         lea           segexit-copybeg(A1),A2
  195.         move.l        A2,_XCEXIT+2(A4)            ;patch the jump instruction
  196.         lea           start-4(PC),A2
  197.    
  198. *        Now we have:    A1 to our new fake segment
  199. *                        A2 to the start of the real seglist
  200.         move.l        #(copyend-copybeg)/4,(A1)+
  201.         move.l        A1,D3
  202.         lsr.l         #2,D3                        ;convert it to a bptr to the list
  203.         move.l        (A2),(A1)+                   ;save our next segment pointer
  204.         clr.l         (A2)                         ;and kill it from the chain
  205. *------ We have the seglist
  206.  
  207.         lea           AutoLoader(PC),A2
  208.         move.l        #(copyend-AutoLoader)-1,D0
  209. copyit  move.b        (A2)+,(A1)+
  210.         dbf           d0,copyit
  211.  
  212. *------        See if they want to do some I/O
  213.         tst.l        _BackGroundIO(A4)
  214.         beq          noio
  215.         lea          current_window(A4),A0
  216.         move.l       A0,D1
  217.         move.l       #1005,D2
  218.         move.l       DOSBase(A4),A6
  219.         callsys      Open
  220.         move.l       d0,_Backstdout(A4)
  221. noio:
  222.         move.l       AbsExecBase.w,A6
  223.  
  224. *------ If under 2.0 Flush cache
  225.    
  226.         moveq    #36,d0
  227.         cmp.w    $14(a6),d0
  228.         bgt.b    nocache
  229.         moveq    #-1,d0
  230.         callsys  CacheClearU
  231.  
  232. nocache:
  233.         
  234.         callsys        Forbid
  235.  
  236. *------ Attach the task to do the dirty work
  237.         move.l        __procname(A4),D1        ; Name of task to start
  238.         move.l        __priority(A4),D2        ; Priority of background task
  239.         move.l        __stack(A4),D4           ; Stack size of created task
  240.  
  241.         move.l        DOSBase(A4),A6
  242.         callsys       CreateProc
  243.         move.l        A6,A3                    ; restore dosbase to close it
  244.         tst.l         D0
  245.         bne           ok
  246.  
  247. *------ Serious problems.  For some reason the CreateProc failed.
  248. *------ We need to free the AlocEntry memory and go home
  249.         move.l        (A7)+,A2
  250.         movea.l       ML_SIZE+ME_ADDR(A2),A1   ;locate our allocated block
  251. *------ Also must get rid of current directory
  252.         move.l        __curdir(A4),D1
  253.         callsys       UnLock
  254.  
  255.         move.l        A2,A0
  256.         move.l        AbsExecBase.w,A6
  257.         callsys       FreeEntry
  258.         move.l        #104,D0
  259.         bra           cliexit
  260.  
  261. ok:
  262. *------ The task started ok, attach the memory we allocated to
  263. *------        its task control block
  264.         move.l        D0,A2
  265.  
  266.         move.l        (a7)+,A1                ;locate the memory we allocated
  267.         lea           -pr_MsgPort(A2),A2
  268.         lea           TC_MEMENTRY(A2),A0
  269.  
  270.  
  271. *        ADDTAIL
  272.         LEA           LH_TAIL(A0),A0
  273.         MOVE.L        LN_PRED(A0),D0
  274.         MOVE.L        A1,LN_PRED(A0)
  275.         MOVE.L        A0,(A1)
  276.         MOVE.L        D0,LN_PRED(A1)
  277.         MOVE.L        D0,A0
  278.         MOVE.L        A1,(A0)
  279.  
  280.         move.l        #0,D0
  281.  
  282. cliexit:
  283.         move.l        AbsExecBase.w,A6
  284.         callsys       Permit
  285.         move.l        A3,A1
  286.         move.l        AbsExecBase.w,A6
  287.         callsys       CloseLibrary
  288.         movem.l       (a7)+,d1-d6/a0-a6
  289.         rts
  290.  
  291. *=======================================================================
  292. *====== Workbench Startup Code =========================================
  293. *=======================================================================
  294.  
  295. fromWorkbench:
  296.  
  297.         move.l        TC_SPLOWER(A3),__base(A4)        ; set base of stack
  298.         add.l         #128,__base(A4)                  ;allow for parms overflow
  299. *------ open the DOS library:
  300.         bsr.w         openDOS
  301.  
  302.         lea           xcexit(PC),A2
  303.         move.l        A2,_XCEXIT+2(A4)                 ;patch the jump instruction
  304.         
  305. *------ we are now set up.  wait for a message from our starter
  306.         bsr.w         waitmsg
  307.         move.l        d0,_WBenchMsg(A4)
  308.         move.l        d0,-(SP)
  309. *
  310.         move.l        d0,a2                            ; get first argument
  311.         move.l        sm_ArgList(a2),d0
  312.         beq.s         do_cons
  313.         move.l        DOSBase(A4),a6
  314.         move.l        d0,a0
  315.         move.l        wa_Lock(a0),d1
  316.         callsys       DupLock
  317.         move.l        d0,__curdir(A4)
  318.         move.l        d0,d1
  319.         callsys       CurrentDir
  320. do_cons:
  321.         move.l        sm_ToolWindow(a2),d1             ; get the window argument
  322.         beq.s         do_main
  323.         move.l        #MODE_OLDFILE,d2
  324.         callsys       Open
  325.         move.l        d0,stdin(A4)
  326.         beq.s         do_main
  327.         lsl.l         #2,d0
  328.         move.l        d0,a0
  329.         move.l        fh_Type(a0),pr_ConsoleTask(A3)
  330. do_main:
  331.         move.l        _WBenchMsg(A4),a0                ; get address of workbench message
  332.         move.l        a0,-(a7)                         ; push argv
  333.         pea           NULL(A4)                         ; push argc
  334.         move.l        sm_ArgList(a0),a0                ; get address of arguments
  335.         move.l        wa_Name(a0),_ProgramName(A4)     ; get name of program
  336. *------ For startup from workbench, there is no reason to go through
  337. *------ The fancy stuff to make the startup work.  Just run the
  338. *------ Code directly
  339.         jsr           __fpinit(PC)
  340.         jsr           __main
  341.         moveq.l       #0,d0
  342.         bra.w         exit2
  343.         
  344.  
  345. ************************************************************************
  346. ************************************************************************
  347. *************                                              *************
  348. ************* Start of code that is copied to fake segment *************
  349. *************                                              *************
  350. ************************************************************************
  351. ************************************************************************
  352.  
  353. copybeg:
  354.         DC.L        (copyend-copybeg)/4
  355. next:   DC.L        0
  356. AutoLoader:
  357.         move.l        a7,d0
  358.         movem.l       d1-d6/a0-a6,-(a7)
  359.         move.l        d0,a5
  360.         move.l        AbsExecBase.w,a6
  361.         lea           LinkerDB,A4                ; load base register
  362.         move.l        a7,_StackPtr(A4)
  363.  
  364.         bsr.w         openDOS
  365.         suba.l        a1,a1
  366.  
  367.         suba.l        a1,a1
  368.         callsys       FindTask
  369.         move.l        d0,A3
  370.  
  371.         move.l        TC_SPLOWER(A3),__base(A4)        ; set base of stack
  372.         add.l         #128,__base(A4)          ;allow for parms overflow
  373.  
  374.         move.l        pr_SegList(A3),a0        ;locate the segment list
  375.         add.l         A0,A0
  376.         add.l         A0,A0                    ;and convert to an APTR
  377.         move.l        12(A0),A1                ;so we can access the segments
  378.         add.l         A1,A1
  379.         add.l         A1,A1
  380.  
  381.         move.l        (A1),seglist(A4)        ;save the remainder for later
  382.         move.l        (A1),12(A0)             ;cut off our segment
  383.  
  384.         move.l        __curdir(A4),D1
  385.         move.l        DOSBase(A4),a6
  386.         callsys       CurrentDir
  387.  
  388. *------ Open Nil: and set up it's input buffer so 
  389. *------ ReadArgs will work.
  390.         lea           nil(pc),a0
  391.         move.l        a0,d1
  392.         move.l        #MODE_OLDFILE,d2
  393.         callsys       Open
  394.         move.l        d0,pr_CIS(a3)
  395.         add.l         d0,d0
  396.         add.l         d0,d0
  397.         move.l        d0,a2
  398.         move.l        argslen(pc),d2
  399.         move.l        d2,fh_End(a2)
  400.         move.l        #0,fh_Pos(a2)        
  401.         
  402.         move.l        AbsExecBase.w,a6
  403.         move.l        d2,d0
  404.         moveq.l       #0,d1
  405.         callsys       AllocMem
  406.         tst.l         d0
  407.         beq.b         segexit
  408.  
  409.         move.l        d0,a0
  410.         lea           commandbuf(pc),a1
  411.         adda.l        proglen(pc),a1
  412.         addq.l        #3,a1               * 3 - is for quotes and trailing space
  413.         subq.l        #1,d2
  414.         blt.b         donecpy
  415. cpy:
  416.         move.b        (a1)+,(a0)+
  417.         dbf           d2,cpy        
  418.             
  419. donecpy:
  420.         lsr.l         #2,d0
  421.         move.l        d0,fh_Buf(a2)
  422.         
  423. *------ Use the cli that our creator set up for us.
  424.         move.l        cli(pc),pr_CLI(a3)
  425.  
  426.         jsr           __fpinit
  427.         pea           commandbuf(PC)
  428.         jsr           __main                        ; call C entrypoint
  429.         addq          #4,A7
  430.  
  431.  
  432. *------ Unlock the directory we set up for them
  433. segexit:
  434.         move.l        DOSBase(A4),a6
  435.         move.l        __curdir(A4),D1
  436.         callsys       UnLock
  437.  
  438.         moveq.l       #0,d0                        ; set successful status
  439. xcexit:
  440. exit2:
  441.         IFEQ          TINY
  442.         move.l        _ONEXIT(A4),d0                ; exit trap function?
  443.         beq.s         exit3
  444.         move.l        d0,a0
  445.         jsr           (a0)
  446.         ENDC
  447.  
  448. exit3:
  449. *------ These must not be PC relative calls since this code is copied
  450.         jsr           __fpterm
  451.         jsr           _MemCleanup                ; cleanup leftover memory alloc.
  452.  
  453.  
  454. done_1c:
  455. *------ if we ran from CLI, skip workbench cleanup:
  456.         tst.l         _WBenchMsg(A4)
  457.         beq.s         exitToDOS
  458.         move.l        DOSBase(A4),a6
  459.         move.l        stdin(A4),d1
  460.         beq.s         done_4
  461.         callsys       Close
  462. done_4:
  463.  
  464. *------ return the startup message to our parent
  465. *        we forbid so workbench can't UnLoadSeg() us
  466. *        before we are done:
  467.         move.l        __curdir(a4),d1
  468.         beq.s         done_5
  469.         callsys       UnLock
  470.  
  471. done_5:
  472.         move.l        AbsExecBase.w,A6
  473.         callsys       Forbid
  474.         move.l        _WBenchMsg(A4),a1
  475.         callsys       ReplyMsg
  476.         bra.b         noCIS
  477.  
  478. *------ this rts sends us back to DOS:
  479. exitToDOS:
  480.         jsr           __freecli
  481.         
  482.         move.l        AbsExecBase.W,a6
  483.         sub.l         a1,a1
  484.         callsys       FindTask
  485.         move.l        d0,a0
  486.         
  487.         move.l        pr_CIS(a0),d1      * test for our input file handle
  488.         beq.b         noCIS
  489.  
  490.         clr.l         pr_CIS(a0)
  491.         move.l        d1,d2
  492.         add.l         d1,d1
  493.         add.l         d1,d1
  494.         move.l        d1,a2
  495.         
  496. *------ First free the buffer we allocated
  497.         move.l        fh_Buf(a2),d1
  498.         add.l         d1,d1
  499.         add.l         d1,d1
  500.         move.l        d1,a1
  501.         move.l        argslen(pc),d0
  502.         callsys       FreeMem
  503.  
  504. *------ Restore fields to 0 
  505.         clr.l         fh_Buf(a2)
  506.         clr.l         fh_End(a2)
  507.  
  508. *------ Close Nil:        
  509.         move.l        d2,d1
  510.         move.l        DOSBase(A4),a6
  511.         callsys       Close
  512.  
  513. noCIS:
  514.         movea.l       _StackPtr(a4),a3            ; save old stack pointer 
  515.  
  516. *------ They are done so unload them
  517.         move.l        seglist(A4),D1
  518.         move.l        DOSBase(A4),a6
  519.         callsys       UnLoadSeg
  520.  
  521.         move.l        a6,a1
  522.         move.l        AbsExecBase.w,a6
  523.         callsys       CloseLibrary                ; close Dos library
  524.  
  525.  
  526.         movea.l       a3,SP                       ; restore stack ptr
  527.         movem.l       (a7)+,d1-d6/a0-a6
  528.         rts
  529.  
  530. *-----------------------------------------------------------------------
  531. *  Open the DOS library:
  532.  
  533. openDOS
  534.                 lea          DOSName(A4),A1
  535.                 moveq.l      #0,D0
  536.                 callsys      OpenLibrary
  537.                 move.l       D0,DOSBase(A4)
  538.                 beq          noDOS
  539.                 rts
  540. *-----------------------------------------------------------------------
  541. noDOS:
  542.                 moveq.l      #100,d0
  543.                 bra          exit2
  544.  
  545. cli:           dc.l         0
  546. argslen:        dc.l         0
  547. proglen:        dc.l         0
  548. nil:            dc.b         'NIL:',0,0
  549.                 
  550. copyend:
  551. commandbuf:
  552.  
  553. ************************************************************************
  554. ************************************************************************
  555. **************                                            **************
  556. ************** End of code that is copied to fake segment **************
  557. **************                                            **************
  558. ************************************************************************
  559. ************************************************************************
  560.  
  561. *-----------------------------------------------------------------------
  562. * This routine gets the message that workbench will send to us
  563. * called with task id in A3
  564.  
  565. waitmsg:
  566.                 lea        pr_MsgPort(A3),a0          ; our process base
  567.                 callsys    WaitPort
  568.                 lea        pr_MsgPort(A3),a0          ; our process base
  569.                 callsys    GetMsg
  570.                 rts
  571.  
  572.         csect        __MERGED,1,0,0,4
  573.  
  574. *------        These externals control the task that is started
  575.         xref        _BackGroundIO                ; flag to indicate background task
  576. *                                                ; wants to do I/O
  577.         xref        __stack                      ; stack space for created task
  578.         xref        __procname                   ; name of process to be created
  579.         xref        __priority                   ; priority to create process at
  580.  
  581.         xref        DOSBase
  582.         xref        MathBase
  583.         xref        MathTransBase
  584. *
  585.         xdef        NULL,SysBase,_WBenchMsg
  586.         xdef        __curdir
  587.         xdef        _OSERR,_FPERR,_SIGFPE,_ONERR,_ONEXIT,_ONBREAK
  588.         xdef        _SIGINT,_Backstdout
  589.         xdef        _ProgramName,_StackPtr,__base
  590. *
  591. memlist        ds.b        LN_SIZE
  592.                dc.w        1
  593.                dc.l        MEMF_PUBLIC
  594. memsize        dc.l        copyend-copybeg
  595.  
  596. _XCEXIT      
  597. @_XCEXIT       dc.w        $4ef9
  598.                dc.l        0
  599. seglist        dc.l        0
  600. NULL           dc.l        0                ;
  601. __base         dc.l        0                ; base of stack
  602. _OSERR         dc.l        0
  603. _FPERR         dc.l        0
  604. _SIGFPE        dc.l        0
  605. _SIGINT        dc.l        0
  606. _ONERR         dc.l        0
  607. _ONEXIT        dc.l        0
  608. _ONBREAK       dc.l        0
  609. __curdir       dc.l        0
  610. SysBase        dc.l        0
  611. _WBenchMsg     dc.l        0
  612. _StackPtr      dc.l        0
  613. dosCmdLen      dc.l        0
  614. dosCmdBuf      dc.l        0
  615. stdin          dc.l        0
  616. _Backstdout    dc.l        0                ;filehandle for I/O
  617. _ProgramName   dc.l        0
  618. DOSName        dc.b        'dos.library',0
  619. current_window dc.b        '*',0
  620.                END
  621.